• 歡迎訪問奇跡の海網站,本站不上傳任何資源,所有資源均來自于網絡,歡迎加入奇跡の海~!奇跡の海-WordPress QQ群
  • 本站下載資源為網絡上收集整理而來,并且以計算機技術研究交流為目的,版權歸原作者所有,僅供大家參考,學習,不存在任何商業目的與商業用途.
  • 本站系統鏡像均來自于官方原版,ed2k可視為P2P下載鏈接。所有操作系統默認均為試用版,如有正版密鑰可以有效激活,本站不提供任何激活和相關服務。

任意檔次寵物生成工具 Ver 2.1 (易語言源碼)

易語言 奇跡の海 2年前 (2018-01-07) 1277次瀏覽 已收錄 0個評論 掃描二維碼

簡介

任意檔次寵物生成工具 Ver 2.1 (易語言源碼)
任意檔次寵物生成工具

代碼

窗口程序集1

.版本 2
.支持庫 iext
.支持庫 mysql

.程序集 窗口程序集1
.程序集變量 提示框計時, 整數型
.程序集變量 角色信息, 文本型, , "2,2"
.程序集變量 被選角色, 文本型
.程序集變量 寵物資料, 文本型, , "0"
.程序集變量 寵物PPT, 整數型

.子程序 _主窗口_創建完畢

置外形圖片 (#主窗口背景, #黑色)
提示消息 (“Power By Leaf.”, #紫色)

.子程序 _關閉_被單擊

銷毀 ()

.子程序 _標題欄_鼠標左鍵被按下, 邏輯型
.參數 橫向位置, 整數型
.參數 縱向位置, 整數型
.參數 功能鍵狀態, 整數型

主窗口.發送信息 (161, 2, 0)

.子程序 _提示文字_鼠標左鍵被按下, 邏輯型
.參數 橫向位置, 整數型
.參數 縱向位置, 整數型
.參數 功能鍵狀態, 整數型

提示框計時 = 0
提示框時鐘.時鐘周期 = 0
連續賦值 (假, 提示框體.可視, 提示文字.可視, 提示圖標.可視, 分組框1.禁止, 分組框2.禁止, 分組框3.禁止)


.子程序 寵物BASE
.參數 BASE數組, 文本型, 數組
.參數 寵物ID, 整數型
.局部變量 i, 整數型
.局部變量 o, 整數型

重定義數組 (BASE數組, 假, 0)
.計次循環首 (取數組下標 (寵物信息, 1), i)
    .如果真 (到整數 (寵物信息 [i] [2]) = 寵物ID)
        .計次循環首 (46, o)
            加入成員 (BASE數組, 寵物信息 [i] [o])
        .計次循環尾 ()
        跳出循環 ()
    .如果真結束

.計次循環尾 ()

.子程序 獲取欄位, 文本型
.參數 帳號, 文本型
.參數 序號, 文本型
.局部變量 記錄集, 整數型
.局部變量 記錄集行數, 整數型
.局部變量 字段值, 文本型
.局部變量 行, 整數型
.局部變量 玩家寵物信息, 整數型, , "5"

執行SQL語句 (MySql句柄, “SELECT * FROM tbl_pet WHERE `CdKey`='” + 帳號 + “' AND RegistNumber=” + 序號)
記錄集 = 取記錄集 (MySql句柄)
記錄集行數 = 取記錄集行數 (記錄集)
.計次循環首 (5, 行)
    玩家寵物信息 [行] = 0
.計次循環尾 ()
.計次循環首 (記錄集行數, 行)
    讀字段值 (記錄集, 97, 字段值)
    .如果真 (到整數 (字段值) = 0)
        讀字段值 (記錄集, 100, 字段值)
        玩家寵物信息 [到整數 (字段值) + 1] = 1
    .如果真結束
    到下一行 (記錄集)
.計次循環尾 ()
.計次循環首 (5, 行)
    .如果真 (玩家寵物信息 [行] = 0)
        返回 (到文本 (行 - 1))
    .如果真結束

.計次循環尾 ()
返回 (“-1”)

.子程序 檢查在線, 邏輯型
.參數 帳號, 文本型

.如果 (取記錄集行數 (查找記錄 (MySql句柄, “tbl_lock”, “*”, “CdKey='” + 帳號 + “'”, “CdKey DESC”)) > 0)
    信息框 (“賬戶在線”, #錯誤圖標, “錯誤”)
    返回 (真)
.否則
    返回 (假)
.如果結束


.子程序 時間到戳, 整數型
.參數 轉換時間, 日期時間型

返回 (取時間間隔 (轉換時間, 到時間 (“1970-01-01 08:00:00”), #秒))

.子程序 提示消息
.參數 提示內容, 文本型, 可空
.參數 提示顏色, 整數型, 可空

處理事件 ()
.如果真 (是否為空 (提示內容))
    提示內容 = “請稍后...”
.如果真結束
.如果真 (是否為空 (提示顏色))
    提示顏色 = #紅色
.如果真結束
提示文字.文本顏色 = 提示顏色
提示文字.標題 = 提示內容
提示框計時 = 0
提示文字.獲取焦點 ()
連續賦值 (真, 提示框體.可視, 提示文字.可視, 提示圖標.可視, 分組框1.禁止, 分組框2.禁止, 分組框3.禁止)
提示框時鐘.時鐘周期 = 1000

.子程序 _提示框時鐘_周期事件

.如果 (提示框計時 > 0)
    提示框計時 = 0
    提示框時鐘.時鐘周期 = 0
    連續賦值 (假, 提示框體.可視, 提示文字.可視, 提示圖標.可視, 分組框1.禁止, 分組框2.禁止, 分組框3.禁止)
.否則
    提示框計時 = 提示框計時 + 1
.如果結束


.子程序 _帳號_按下某鍵, 邏輯型
.參數 鍵代碼, 整數型
.參數 功能鍵狀態, 整數型
.局部變量 記錄集, 整數型
.局部變量 記錄集行數, 整數型
.局部變量 字段值, 文本型, , "3"
.局部變量 循環變量, 整數型

角色名.標題 = “尚未選擇”
帳號圖示.正常圖片 = #放大鏡
連續賦值 (真, 左側.禁止, 右側.禁止)
連續賦值 (假, 左側.選中, 右側.選中)
.如果真 (鍵代碼 = #回車鍵)
    提示消息 ()
    重定義數組 (角色信息, 假, 2, 2)
    .如果真 (取文本長度 (帳號.內容) > 0)
        帳號圖示.正常圖片 = #問號
        ' 執行SQL語句 (MySql句柄, “SELECT `DataPlaceNumber`,`RegistNumber`,`Name` FROM tbl_character WHERE `CdKey`='” + 帳號.內容 + “' ORDER BY `DataPlaceNumber` ASC”)
        執行SQL語句 (MySql句柄, “SELECT `DataPlaceNumber`,`RegistNumber`,`Name` FROM tbl_character WHERE `CdKey`='” + 帳號.內容 + “' ORDER BY `DataPlaceNumber` ASC”)
        記錄集 = 取記錄集 (MySql句柄)
        記錄集行數 = 取記錄集行數 (記錄集)
        帳號圖示.正常圖片 = #叉叉
        .如果 (記錄集行數 > 0)
            帳號圖示.正常圖片 = #對勾
            .如果 (記錄集行數 = 1)
                讀字段值 (記錄集, 0, 字段值 [1])
                讀字段值 (記錄集, 1, 字段值 [2])
                讀字段值 (記錄集, 2, 字段值 [3])
                .如果 (到整數 (字段值 [1]) = 0)
                    左側.禁止 = 假
                .否則
                    右側.禁止 = 假
                .如果結束
                角色信息 [到整數 (字段值 [1]) + 1] [1] = 字段值 [2]
                角色信息 [到整數 (字段值 [1]) + 1] [2] = 字段值 [3]
            .否則
                .如果 (記錄集行數 = 2)
                    .計次循環首 (記錄集行數, 循環變量)
                        讀字段值 (記錄集, 0, 字段值 [1])
                        讀字段值 (記錄集, 1, 字段值 [2])
                        讀字段值 (記錄集, 2, 字段值 [3])
                        角色信息 [到整數 (字段值 [1]) + 1] [1] = 字段值 [2]
                        角色信息 [到整數 (字段值 [1]) + 1] [2] = 字段值 [3]
                        到下一行 (記錄集)
                    .計次循環尾 ()
                    提示消息 (“搜索成功”, #墨綠)
                    連續賦值 (假, 左側.禁止, 右側.禁止)
                .否則
                    帳號圖示.正常圖片 = #叉叉
                    連續賦值 (真, 左側.禁止, 右側.禁止)
                    提示消息 (“數據異常”)
                .如果結束

            .如果結束

        .否則
            提示消息 (“無此賬戶”)
        .如果結束


    .如果真結束
    返回 (假)
.如果真結束


.子程序 _寵編號_按下某鍵, 邏輯型
.參數 鍵代碼, 整數型
.參數 功能鍵狀態, 整數型

寵物名.標題 = “尚未選擇”
連續賦值 (真, 掉檔_體力.禁止, 掉檔_力量.禁止, 掉檔_強度.禁止, 掉檔_速度.禁止, 掉檔_魔法.禁止, 分配按鈕.禁止)
.如果真 (鍵代碼 = #減號鍵)
    返回 (假)
.如果真結束
.如果真 (鍵代碼 = #回車鍵)
    寵物驗證.獲取焦點 ()
    _寵物驗證_被單擊 ()
    返回 (假)
.如果真結束


.子程序 _左側_被單擊

.如果 (取文本長度 (角色信息 [1] [2]) > 0)
    角色名.標題 = 角色信息 [1] [2]
    被選角色 = 角色信息 [1] [1]
.否則
    角色名.標題 = “無角色”
.如果結束


.子程序 _右側_被單擊

.如果 (取文本長度 (角色信息 [2] [2]) > 0)
    角色名.標題 = 角色信息 [2] [2]
    被選角色 = 角色信息 [2] [1]
.否則
    角色名.標題 = “無角色”
.如果結束


.子程序 _寵物驗證_被單擊

寵物驗證.獲取焦點 ()
.如果真 (取文本長度 (寵編號.內容) > 0 且 到整數 (寵編號.內容) > 0)
    寵物BASE (寵物資料, 到整數 (寵編號.內容))
    .如果 (取數組成員數 (寵物資料) > 40)
        寵物PPT = 到整數 (寵物資料 [6]) × 64 × 64 × 64 × 64 + 到整數 (寵物資料 [7]) × 64 × 64 × 64 + 到整數 (寵物資料 [8]) × 64 × 64 + 到整數 (寵物資料 [9]) × 64 + 到整數 (寵物資料 [10])
        寵物名.文本顏色 = #深灰
        寵物名.標題 = 寵物資料 [1]
        連續賦值 (假, 掉檔_體力.禁止, 掉檔_力量.禁止, 掉檔_強度.禁止, 掉檔_速度.禁止, 掉檔_魔法.禁止, 分配按鈕.禁止)
    .否則
        寵物名.文本顏色 = #紅色
        寵物名.標題 = “無數據”
        連續賦值 (真, 掉檔_體力.禁止, 掉檔_力量.禁止, 掉檔_強度.禁止, 掉檔_速度.禁止, 掉檔_魔法.禁止, 分配按鈕.禁止)
    .如果結束

.如果真結束


.子程序 _分配按鈕_被單擊
.局部變量 SQL語句, 文本型
.局部變量 記錄集, 整數型
.局部變量 記錄集行數, 整數型
.局部變量 分配欄位, 文本型
.局部變量 分配寵物BP, 文本型, , "5"
.局部變量 分配寵物PPT, 整數型
.局部變量 i, 整數型

.如果真 (取文本長度 (被選角色) < 1 或 角色名.標題 = “尚未選擇” 或 角色名.標題 = “無角色”)
    提示消息 (“請選擇角色”)
    返回 ()
.如果真結束
.如果真 (掉檔_體力.現行選中項 + 掉檔_力量.現行選中項 + 掉檔_強度.現行選中項 + 掉檔_速度.現行選中項 + 掉檔_魔法.現行選中項 > 20)
    提示消息 (“掉檔總數 > 20”)
    返回 ()
.如果真結束
.如果真 (檢查在線 (帳號.內容))
    提示消息 (“賬戶在線”)
    返回 ()
.如果真結束
分配欄位 = 獲取欄位 (帳號.內容, 被選角色)
.如果真 (到整數 (分配欄位) = -1)
    提示消息 (“角色寵物欄不足”)
    返回 ()
.如果真結束
分配寵物PPT = 寵物PPT - 掉檔_體力.現行選中項 × 64 × 64 × 64 × 64 - 掉檔_力量.現行選中項 × 64 × 64 × 64 - 掉檔_強度.現行選中項 × 64 × 64 - 掉檔_速度.現行選中項 × 64 - 掉檔_魔法.現行選中項
.如果真 (分配寵物PPT < 0)
    分配寵物PPT = 0
.如果真結束
分配寵物PPT = 分配寵物PPT + 34087042
分配寵物BP [1] = 到文本 (到整數 (寵物資料 [6]) × 20 + 80 - 掉檔_體力.現行選中項 × 20)
分配寵物BP [2] = 到文本 (到整數 (寵物資料 [7]) × 20 + 80 - 掉檔_力量.現行選中項 × 20)
分配寵物BP [3] = 到文本 (到整數 (寵物資料 [8]) × 20 + 80 - 掉檔_強度.現行選中項 × 20)
分配寵物BP [4] = 到文本 (到整數 (寵物資料 [9]) × 20 + 80 - 掉檔_速度.現行選中項 × 20)
分配寵物BP [5] = 到文本 (到整數 (寵物資料 [10]) × 20 + 80 - 掉檔_魔法.現行選中項 × 20)
.計次循環首 (10, i)
    .如果真 (寵物資料 [i + 36] = “”)
        寵物資料 [i + 36] = “-1”
    .如果真結束

.計次循環尾 ()
SQL語句 = “INSERT INTO tbl_pet values (3,'” + 寵物資料 [31] + “','” + 寵物資料 [31] + “',0,0,0,0,0,1,1,1,'” + 分配寵物BP [1] + “','” + 分配寵物BP [2] + “','” + 分配寵物BP [3] + “','” + 分配寵物BP [4] + “','” + 分配寵物BP [5] + “',0,'” + 寵物資料 [5] + “','” + 寵物資料 [16] + “','” + 寵物資料 [17] + “','” + 寵物資料 [18] + “','” + 寵物資料 [19] + “','” + 寵物資料 [20] + “','” + 寵物資料 [21] + “','” + 寵物資料 [22] + “','” + 寵物資料 [23] + “','” + 寵物資料 [24] + “','” + 寵物資料 [25] + “','” + 寵物資料 [28] + “','” + 寵物資料 [29] + “','” + 寵物資料 [14] + “','” + 寵物資料 [15] + “',0,0,0,0,0,” + 到文本 (時間到戳 (取現行時間 ())) + “,0,0,0,0,0,0,0,” + 到文本 (分配寵物PPT) + “,0,0,0,0,0,'” + 寵物資料 [30] + “',0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,'” + 寵物資料 [2] + “',0,0,0,'” + 寵物資料 [37] + “','” + 寵物資料 [38] + “','” + 寵物資料 [39] + “','” + 寵物資料 [40] + “','” + 寵物資料 [41] + “','” + 寵物資料 [42] + “','” + 寵物資料 [43] + “','” + 寵物資料 [44] + “','” + 寵物資料 [45] + “','” + 寵物資料 [46] + “',0,0,0,0,0,0,0,0,0,0,'” + 寵物資料 [1] + “','','” + 帳號.內容 + “','” + 帳號.內容 + “','” + 角色名.標題 + “',0,'” + 帳號.內容 + “','” + 被選角色 + “',” + 分配欄位 + “,0)”
.如果 (執行SQL語句 (MySql句柄, SQL語句))
    提示消息 (“分配寵物成功”, #墨綠)
.否則
    提示消息 (“分配寵物失敗”)
.如果結束

窗口程序集2

.版本 2
.支持庫 iext
.支持庫 mysql

.程序集 窗口程序集2

.子程序 __啟動窗口_創建完畢

置外形圖片 (#啟動背景, #黑色)
地址.內容 = 讀配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “地址”, “127.0.0.1”)
端口.內容 = 讀配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “端口”, “3306”)
賬戶.內容 = 讀配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “賬戶”, “root”)
密碼.內容 = 讀配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “密碼”, “”)
庫名.內容 = 讀配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “庫名”, “rogue”)

.子程序 __啟動窗口_鼠標左鍵被按下, 邏輯型
.參數 橫向位置, 整數型
.參數 縱向位置, 整數型
.參數 功能鍵狀態, 整數型

_啟動窗口.發送信息 (161, 2, 0)

.子程序 _取消按鈕_被單擊

銷毀 ()

.子程序 _連接按鈕_被單擊
.局部變量 文件內容, 文本型
.局部變量 分割文件, 文本型, , "0"
.局部變量 分割行, 文本型, , "0"
.局部變量 循環變量, 整數型
.局部變量 循環變量2, 整數型

提示標簽.文本顏色 = #灰色
提示標簽.標題 = “連接中..”
MySql句柄 = 連接MySql (地址.內容, 賬戶.內容, 密碼.內容, 庫名.內容, 到整數 (端口.內容))
.如果 (MySql句柄 = 0)
    提示標簽.文本顏色 = #紅色
    提示標簽.標題 = “連接失敗”
.否則
    .如果真 (取反 (文件是否存在 (取運行目錄 () + “\enemybase.txt”)))
        信息框 (“請將魔力服務端內的” + #換行符 + “enemybase.txt 文件” + #換行符 + “放置于程序同目錄!”, #錯誤圖標, “缺少文件”)
        提示標簽.文本顏色 = #紫色
        提示標簽.標題 = “缺少文件”
        斷開MySql (MySql句柄)
        返回 ()
    .如果真結束
    文件內容 = 讀入文本 (打開文件 (取運行目錄 () + “\enemybase.txt”, , ), )
    分割文件 = 分割文本 (文件內容, #換行符, )
    重定義數組 (寵物信息, 假, 取數組成員數 (分割文件), 46)
    .計次循環首 (取數組成員數 (分割文件), 循環變量)
        分割行 = 分割文本 (分割文件 [循環變量], 字符 (9), )
        .如果真 (取數組成員數 (分割行) > 10)
            .計次循環首 (取數組成員數 (分割行), 循環變量2)
                寵物信息 [循環變量] [循環變量2] = 分割行 [循環變量2]
            .計次循環尾 ()
        .如果真結束

    .計次循環尾 ()
    寫配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “地址”, 地址.內容)
    寫配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “端口”, 端口.內容)
    寫配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “賬戶”, 賬戶.內容)
    寫配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “密碼”, 密碼.內容)
    寫配置項 (取運行目錄 () + “\Config.ini”, “數據庫配置”, “庫名”, 庫名.內容)
    載入 (主窗口, , 假)
    銷毀 ()
.如果結束

源碼下載

下載地址
密碼:nt9a


版權聲明:本站所有文章和資源使用CC BY-NC-SA 4.0協議授權發布 , 轉載應當以相同方式注明文章來自“SeaOMC.COM->任意檔次寵物生成工具 Ver 2.1 (易語言源碼)!在下邊可以分享本文哦!
喜歡 (0)
[]
分享 (0)
奇跡の海
關于作者:
一個WordPress菜鳥!
發表我的評論
取消評論

表情 貼圖 加粗 刪除線 居中 斜體 簽到

Hi,您需要填寫昵稱和郵箱!

  • 昵稱 (必填)
  • 郵箱 (必填)
  • 網址
中国福利彩票36选7开奖结果