• 歡迎訪問奇跡の海網站,本站不上傳任何資源,所有資源均來自于網絡,歡迎加入奇跡の海~!奇跡の海-WordPress QQ群
  • 本站下載資源為網絡上收集整理而來,并且以計算機技術研究交流為目的,版權歸原作者所有,僅供大家參考,學習,不存在任何商業目的與商業用途.
  • 本站系統鏡像均來自于官方原版,ed2k可視為P2P下載鏈接。所有操作系統默認均為試用版,如有正版密鑰可以有效激活,本站不提供任何激活和相關服務。

Windows下用BAT命令自動設置IP地址和DNS

批處理 奇跡の海 1年前 (2018-10-04) 371次瀏覽 已收錄 0個評論 掃描二維碼

windows下的.bat文件或者.cmd文件都可以直接雙擊執行,里面寫的批處理命令可以幫助我們方便的處理一些事情。
Windows下用BAT命令自動設置IP地址和DNS
比如我經常到實驗室去上課,實驗室的有線網絡需要設置本地ip地址,而在宿舍是需要DHCP自動獲取ip地址的,每次都要打開網絡適配器更改ip地址很麻煩,我們可以借助批處理文件幫助我們配置它。

@echo off      
::雙冒號表示注釋,注釋只能單獨一行寫,@表示不讓執行的命令又顯示在屏幕上
cls           
::清屏
color 0A 
::設置顯示字體顏色
echo IP地址更改小工具 
set IP=10.131.20.38 
set MASK=255.255.255.0 
set GATEWAY=10.131.20.1 
set NAME="本地連接" 
set DNS1="114.114.114.114"
set DNS2="8.8.8.8"
 
:ENTER
echo.
echo. 
echo 更改為309的IP 請按 1  
echo 手動更改IP 請按 2 
echo 設置ip動態獲取 請按 3
echo 設置dns動態獲取 請按 4
echo 手動設置dns 請按 5
echo 顯示網絡配置信息 請按 6
echo 退出 請按 7
 
set /p KEY= [您的選擇是:]     
::  /p表示將KEY設置為輸入行
if %KEY% == 1 goto ONE 
if %KEY% == 2 goto TWO 
if %KEY% == 3 goto THREE
if %KEY% == 4 goto FOUR
if %KEY% == 5 goto FIVE
if %KEY% == 6 goto SIX
if %KEY% == 7 goto EXIT
 
:TWO 
ECHO 您選擇了手工修改設置。 
ECHO. 
echo 默認IP地址是%IP%,回車輸入默認地址 
set /p IP= [請輸入IP地址:] 
echo. 
echo 默認MASK是%MASK%,回車輸入默認值 
set /p MASK= [請輸入 子網掩碼 地址:] 
echo. 
echo 默認GATEWAY是%GATEWAY%,回車輸入默認值 
set /p GATEWAY= [請輸入 網關 地址:] 
echo. 
 
:ONE 
echo 正在自動更改IP...... 
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY% 
echo IP地址/子網掩碼/網關設置完成 
goto ENTER
 
:THREE
netsh interface ip set address name="本地連接" source=dhcp
echo IP地址設置完成 
goto ENTER
 
:FOUR
netsh interface ip set dns name="本地連接" source=dhcp 
echo dns設置完成 
goto ENTER
 
:FIVE
echo 默認DNS1地址是%DNS1%,回車輸入默認地址 
set /p DNS1= [請輸入DNS1地址:] 
echo. 
echo 默認DNS2地址是%DNS2%,回車輸入默認地址 
set /p DNS2= [請輸入DNS2地址:] 
echo.
 
echo 正在設置DNS......
netsh interface ip add dns "本地連接" %DNS1% index=1 >nul 
netsh interface ip add dns "本地連接" %DNS2% index=2 >nul 
echo dns設置完成 
goto ENTER
 
:SIX
ipconfig /all
goto ENTER
 
:EXIT
pause
exit

版權聲明:本站所有文章和資源使用CC BY-NC-SA 4.0協議授權發布 , 轉載應當以相同方式注明文章來自“SeaOMC.COM->Windows下用BAT命令自動設置IP地址和DNS!在下邊可以分享本文哦!
喜歡 (0)
[]
分享 (0)
奇跡の海
關于作者:
一個WordPress菜鳥!
發表我的評論
取消評論

表情 貼圖 加粗 刪除線 居中 斜體 簽到

Hi,您需要填寫昵稱和郵箱!

  • 昵稱 (必填)
  • 郵箱 (必填)
  • 網址
中国福利彩票36选7开奖结果